Brīdinājumu par interneta savienojumu iestatīšana operētājsistēmā Windows 10

Ja jūsu internets darbojas uz augšu, un jums tas jādaraizsekojiet, kad jums ir vai nav savienojuma, vienkāršākais veids, kā to izdarīt, ir sekot līdzi Wi-Fi simbolam sistēmas teknē operētājsistēmā Windows 10. Pazaudējot interneta savienojumu, uz WiFi simbola parādās dzeltena izsaukuma zīme. Varat arī piespraust vietni. Ja nevarat pievērst uzmanību sistēmas teknei un pingēšana jums šķiet apnicīga, operētājsistēmā Windows 10 varat iestatīt audio interneta savienojuma brīdinājumus, izmantojot vienkāršu skriptu.

SPOILER BRĪDINĀJUMS: Ritiniet uz leju un skatieties video pamācību šī raksta beigās.

Brīdinājumi par interneta savienojumu

Šo skriptu sākotnēji uzrakstīja superlietotājsFabby un uzlabots ar VMMF. Skriptam ir nepieciešams lejupielādēt Win32 bezmaksas utilītu, ko sauc par GNU utilītprogrammām. Izņemiet to un apskatiet tālāk redzamo mapi EXE ar nosaukumu Sleep.exe.

UnxUtilsusrlocalwbin

Tas tiks izmantots, lai starp pārbaudēm pievienotu gaidīšanas laiku. Šim EXE vajadzētu būt tajā pašā mapē, kurā saglabājat skriptu. Jums nav nepieciešams nekas cits, tāpēc jūtieties brīvi to izdzēst.

Atveriet Notepad un ielīmējiet tajā. Saglabājiet to ar CMD paplašinājumu un palaidiet failu. Failu sound.vbs izveido skripts, tāpēc par to nav jāuztraucas.

@ECHO OFF
:whileNoInternet
set "host=8.8.8.8"
::check if internet is working
PING -n 1 -w 5000 "%host%" | findstr /r /c:"[0-9] *ms"
if %errorlevel% neq 0 (
::the internet is not working keep cheking until it does
echo No internet yet %TIME%
GOTO whileNoInternet
)
echo we gained internet
::the internet is working play internet ON song
@echo off
set "file=InternetON_GOGOGO.mp3"
( echo Set Sound = CreateObject("WMPlayer.OCX.7"^)
echo Sound.URL = "%file%"
echo Sound.Controls.play
echo do while Sound.currentmedia.duration = 0
echo wscript.sleep 100
echo loop
echo wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000) >sound.vbs
start /min sound.vbs
@ECHO OFF
:whileInternet
sleep.exe 5s
::check if internet is still working
PING -n 1 -w 1000 "%host%" | findstr /r /c:"[0-9] *ms"
if %errorlevel% == 0 (
::the internet is still working keep cheking until it does not
echo We have internet %TIME%
GOTO whileInternet
)
:: detect possible internet glitches (do not trust the first failure)
echo internet glitch detected
sleep.exe 10s
PING -n 1 -w 1000 "%host%" | findstr /r /c:"[0-9] *ms"
if %errorlevel% == 0 (
::the internet is still working keep cheking until it does not
echo We have internet %TIME%
GOTO whileInternet
)
:: if it failed twice in a row most likely internet is down
echo we lost internet
::the internet is not working anymore, play internet OFF song
@echo off
set "file=InternetHasFallen.mp3"
( echo Set Sound = CreateObject("WMPlayer.OCX.7"^)
echo Sound.URL = "%file%"
echo Sound.Controls.play
echo do while Sound.currentmedia.duration = 0
echo wscript.sleep 100
echo loop
echo wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000) >sound.vbs
start /min sound.vbs
::start monitoring if it comes back
GOTO whileNoInternet

Tas ir viss, kas jums jādara. Komandu uzvednes logs paliks atvērts, pārbaudot jūsu interneta savienojuma statusu. Ja tas mainās, jūs dzirdēsit izslēgšanas skaņu.