Hoe u internetverbindingswaarschuwingen instelt op Windows 10

Als uw internet werkt, en u moethoud bij of u een verbinding hebt of niet, de eenvoudigste manier om dit te doen is het WiFi-symbool in het systeemvak op Windows 10 in de gaten te houden. Wanneer u de internetverbinding verliest, verschijnt een geel uitroepteken op het WiFi-symbool. U kunt ook een website pingen. Als u het systeemvak niet in de gaten kunt houden en pingen voor u te vervelend lijkt, kunt u met een eenvoudig script audio-internetverbinding instellen op Windows 10.

SPOILER ALERT: Scrol omlaag en bekijk de videozelfstudie aan het einde van dit artikel.

Waarschuwingen voor internetconnectiviteit

Dit script is oorspronkelijk geschreven door SuperuserFabby, en verbeterd door VMMF. Voor het script moet u een gratis hulpprogramma downloaden met de naam GNU-hulpprogramma's voor Win32. Pak het uit en kijk in de volgende map naar een EXE met de naam Sleep.exe.

UnxUtilsusrlocalwbin

Dit wordt gebruikt om een ​​wachttijd tussen de cheques toe te voegen. Deze EXE moet zich in dezelfde map bevinden als waarin u het script opslaat. U heeft verder niets nodig, dus u kunt het verwijderen.

Open Kladblok en plak het volgende erin. Sla het op met een CMD-extensie en voer het bestand uit. Het sound.vbs-bestand wordt door het script gemaakt, dus maak je geen zorgen.

@ECHO OFF
:whileNoInternet
set "host=8.8.8.8"
::check if internet is working
PING -n 1 -w 5000 "%host%" | findstr /r /c:"[0-9] *ms"
if %errorlevel% neq 0 (
::the internet is not working keep cheking until it does
echo No internet yet %TIME%
GOTO whileNoInternet
)
echo we gained internet
::the internet is working play internet ON song
@echo off
set "file=InternetON_GOGOGO.mp3"
( echo Set Sound = CreateObject("WMPlayer.OCX.7"^)
echo Sound.URL = "%file%"
echo Sound.Controls.play
echo do while Sound.currentmedia.duration = 0
echo wscript.sleep 100
echo loop
echo wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000) >sound.vbs
start /min sound.vbs
@ECHO OFF
:whileInternet
sleep.exe 5s
::check if internet is still working
PING -n 1 -w 1000 "%host%" | findstr /r /c:"[0-9] *ms"
if %errorlevel% == 0 (
::the internet is still working keep cheking until it does not
echo We have internet %TIME%
GOTO whileInternet
)
:: detect possible internet glitches (do not trust the first failure)
echo internet glitch detected
sleep.exe 10s
PING -n 1 -w 1000 "%host%" | findstr /r /c:"[0-9] *ms"
if %errorlevel% == 0 (
::the internet is still working keep cheking until it does not
echo We have internet %TIME%
GOTO whileInternet
)
:: if it failed twice in a row most likely internet is down
echo we lost internet
::the internet is not working anymore, play internet OFF song
@echo off
set "file=InternetHasFallen.mp3"
( echo Set Sound = CreateObject("WMPlayer.OCX.7"^)
echo Sound.URL = "%file%"
echo Sound.Controls.play
echo do while Sound.currentmedia.duration = 0
echo wscript.sleep 100
echo loop
echo wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000) >sound.vbs
start /min sound.vbs
::start monitoring if it comes back
GOTO whileNoInternet

Dat is alles wat u hoeft te doen. Een opdrachtpromptvenster blijft geopend en controleert de status van uw internetverbinding. Als het verandert, hoort u het geluid Uit.